[X] My Assistant

[tfisher]

I've been playing with the released raw ISS images (thanks to Bjorn for the img2png program!) trying to produce a better image near Huygen's descent location.

Here's what I've come up with. I started with images from two different imaging sequences, applied a Fourier bandpass filter, and stacked the images from the same pass. Because of different lighting conditions, or atmospheric conditions, or something, the images are significantly different, so I combined them as red and blue layers instead of just stacking further. Green is produced by the product of red and blue chanels, and a further contrast adjustment is also made.


I believe Huygens descent location is in the upper left corner. The correspondence with one of Rene's beautiful mosiacs is given here:


Unfortunately the geometry is different enough I can't really overlay the mosaic with the ISS image...

[tfisher]

I've been working on improving my Titan processing methods. I've now got reasonable residual flatfielding and map projection based on the PDS data index information, and thanks to ImageJ's nice macro abilities the process of flattening, sharpening, and map projecting an image is pretty well automated. (which maybe means I should have bitten the bullet and used ISIS, but ah well...)

The "lines" turn out to be fully the result of residual flatfield artifacts, which unfortunately are quite persistant. The "sunrise effect" was a combination of residual flatfield and poor alignment.

I'll share with you the in-progress version of an improved super-resolution stack at the Huygen's landing site (at the moment using the same 5 images from Ta and Tb passes previously mentioned):



A question for volcanopele, if you're reading this: do you know how large the errors in the PDS latitude/longitude info can be? I've been trying to improve slightly on the registration by a small additional translation, but have been hoping error in size or rotation will be negligable.

[elakdawalla]

I've been working on improving my Titan processing methods.  I've now got reasonable residual flatfielding and map projection based on the PDS data index information, and thanks to ImageJ's nice macro abilities the process of flattening, sharpening, and map projecting an image is pretty well automated.  (which maybe means I should have bitten the bullet and used ISIS, but ah well...) 

You are actually using ImageJ for map projection? How??

--Emily

[tfisher]

You are actually using ImageJ for map projection?  How??

There is a plugin called TurboReg which will attempt automated registration of images or allows manual or scripted transformation. I'm currently using it in a script which uses TurboReg to perform a bilinear transformation moving the four corners of the image to lattitude and longitude coordinates based on the PDS index.tab information (really I've been grabbing it from the PDS search result page for each image individually -- the data at the bottom labelled "Image Parameters" is equivalent to a row from that table...) Really this isn't a true map projection: once the image is large enough curvature effects won't be handled properly. For the area I'm dealing with, though, of a few square degrees near the equator, the distortion is negligable.

On the odd chance you're interested in the script itself, here's the current form. (somewhat ugly, use at your own risk, etc...) It wants to start with a .png image open (produced by Bjorn's img2png and opened with the Image IO plugin) and to have the "Image Parameters" data saved as the same name as the image with a ".txt" extension.

CODE

// hardwire parameters
flatname = "flat-try4.tif";
filtername = "fft-filter-try1.tif";
dirname = "C:/stuff/cassini-work/"

map_width = 2000.0;
map_height= 2000.0;
map_lon1 = 195.0;
map_lon2 = 186.0;
map_lat1 = -6.0;
map_lat2 = -15.0;

// ------------------------- perform flattening and sharpening
imagename=getTitle();
extension=indexOf(imagename,".png");
if (extension>=0) basename=substring(imagename,0,extension);
else basename=imagename;
imageCalculator("Divide create 32-bit", imagename, flatname);

// new method: use a custom filter
run("Custom Filter...", "filter="+filtername);
rename(basename+"-flat");

// older method: subtract 85% of a low-pass filtered image
//rename("flat-temp");
//run("Duplicate...", "title=fft-temp");
//run("Bandpass Filter...", "filter_large=512 filter_small=85 suppress=None tolerance=5");
//run("Multiply...", "value=.85");
//imageCalculator("Difference create 32-bit", "flat-temp","fft-temp");
//rename(basename+"-flat");
//selectWindow("flat-temp");
//close();
//selectWindow("fft-temp");
//close();

// ------------------------ perform map transformation

metaname = basename + ".txt";
run("Edit...", "open="+dirname+metaname);
metainfo = getInfo();

y0 = getNumericTag("LOWER_LEFT_LATITUDE",metainfo);
x0 = getNumericTag("LOWER_LEFT_LONGITUDE",metainfo);
y1 = getNumericTag("LOWER_RIGHT_LATITUDE",metainfo);
x1 = getNumericTag("LOWER_RIGHT_LONGITUDE",metainfo);
y2 = getNumericTag("UPPER_LEFT_LATITUDE",metainfo);
x2 = getNumericTag("UPPER_LEFT_LONGITUDE",metainfo);
y3 = getNumericTag("UPPER_RIGHT_LATITUDE",metainfo);
x3 = getNumericTag("UPPER_RIGHT_LONGITUDE",metainfo);

run("TurboReg ", "-transform -window "+basename+"-flat "
    + toString(map_width) + " " + toString(map_height) + " "
    + "-bilinear " + "0 511 " + toString(map_lon(x0)) + " " + toString(map_lat(y0)) + " "
    +  "511 511 " + toString(map_lon(x1)) + " " + toString(map_lat(y1)) + " "
    + "0 0 " + toString(map_lon(x2)) + " " + toString(map_lat(y2)) + " "
    + "511 0 " + toString(map_lon(x3)) + " " + toString(map_lat(y3)) + " "
    + "-showOutput" );
rename(basename+"-flat-map");
setSlice(2);
run("Delete Slice");
selectWindow(basename+"-flat");
close();

return;

// --------------------- functions --------------------------

// return device coordinates from longitude
function map_lon(x) {
 return (map_lon1-x)*(map_width/(map_lon1-map_lon2));
}

// return device coordinates from latitude
function map_lat(y) {
 return (map_lat1-y)*(map_height/(map_lat1-map_lat2));
}

// This function returns the numeric value of the
// specified tag given in infostring. Returns NaN
// (not-a-number) if the tag is not found or it
// does not have a numeric value.
function getNumericTag(tag,infostring) {
 value = getTag(tag,infostring);
 if (value=="") return NaN;
 index3 = indexOf(value, "\\");
 if (index3>0)
   value = substring(value, 0, index3);
 value = 0 + value; // convert to number
 return value;
}

// This function returns the value of the specified
// tag given in infostring as a string. Returns ""
// if the tag is not found.
function getTag(tag,infostring) {
   index1 = indexOf(infostring, tag);
   if (index1==-1) return "";
   index1 = indexOf(infostring, ":", index1);
   if (index1==-1) return "";
   index2 = indexOf(infostring, "\n", index1);
   value = substring(infostring, index1+1, index2);
   return value;
}